blob: 37c17fd36b5e15180cc9226444801ffad8da1782 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Anas Elgarhy <anas.elgarhy.dev@gmail.com>
pkgname=proxelar-git
_pkgname=proxelar
pkgver=0.4.7.r0.g759cf89
pkgrel=1
pkgdesc='Programmable MITM proxy that intercepts HTTP/HTTPS traffic. With a TUI, terminal, and web GUI interface'
arch=('x86_64' 'aarch64' 'riscv64')
url='https://github.com/emanuele-em/proxelar'
license=('MIT')
depends=('lua')
makedepends=('cargo')
options=(!lto)
provides=('proxelar')
conflicts=('proxelar' 'proxelar-bin')
source=("${_pkgname}-main::git+$url.git#branch=main")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}-main"
git describe --long --abbrev=7 --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${_pkgname}-main"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "${_pkgname}-main"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
package() {
cd "${_pkgname}-main"
install -Dm0755 target/release/proxelar "$pkgdir/usr/bin/proxelar"
install -Dm644 LICENSE-MIT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
}
# vim: ts=4 sw=4 et:
|