blob: 1de8e47a4780469953617e18ba8e10b881d63307 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Dominik Csapak <dominik.csapak@gmail.com>
pkgname=proxmox-backup-client
pkgver=0.8.15
pkgrel=1
pkgdesc="Client for Proxmox Backup Server"
arch=('x86_64' 'aarch64')
url="https://www.proxmox.com"
license=('AGPL3')
depends=('gcc-libs'
'fuse3'
'pam'
'systemd-libs'
'acl'
)
makedepends=('cargo' 'clang' 'git' 'llvm' 'python-docutils')
source=(
"$pkgname-$pkgver::git://git.proxmox.com/git/proxmox-backup.git#tag=v$pkgver"
"0001-adapt-cargo-toml-and-remove-systemd-linking.patch"
"0002-remove-apt-dependency.patch"
)
sha512sums=('SKIP'
'40d7d1b696b90d5f4d3b7aca7ab792e0059211de9509af3222586e24fa4641caedc4aaff2b9b5573c5bd7c0202bf3094afdfbfcdce847a363917fd748b46f0d7'
'd5bd03b046990d0f31269233c0ad28f609d01e0ae056530125901c395a75f62ebbe393e7cfc54787bfdf36c79888740ef1dcfed569b6a30a182893586c4218ef')
prepare() {
cd "$pkgname-$pkgver"
patch --forward --strip=1 --input="${srcdir}/0001-adapt-cargo-toml-and-remove-systemd-linking.patch"
patch --forward --strip=1 --input="${srcdir}/0002-remove-apt-dependency.patch"
}
build() {
cd "$pkgname-$pkgver"
cargo build --release --bin proxmox-backup-client --bin pxar --bin dump-catalog-shell-cli
cd docs
BUILD_MODE=release make proxmox-backup-client.1 pxar.1
}
check() {
cd "$pkgname-$pkgver"
cargo test --release --bin proxmox-backup-client --bin pxar
}
package() {
cd "$pkgname-$pkgver"
install -Dm755 "target/release/proxmox-backup-client" "$pkgdir/usr/bin/proxmox-backup-client"
install -Dm755 "target/release/pxar" "$pkgdir/usr/bin/pxar"
install -Dm644 "docs/proxmox-backup-client.1" "$pkgdir/usr/share/man/man1/proxmox-backup-client.1"
install -Dm644 "docs/pxar.1" "$pkgdir/usr/share/man/man1/pxar.1"
install -Dm644 "debian/proxmox-backup-client.bc" "$pkgdir/usr/share/bash-completion/completions/proxmox-backup-client"
install -Dm644 "debian/pxar.bc" "$pkgdir/usr/share/bash-completion/completions/pxar"
install -Dm644 "zsh-completions/_proxmox-backup-client" "$pkgdir/usr/share/zsh/site-functions/_proxmox-backup-client"
install -Dm644 "zsh-completions/_pxar" "$pkgdir/usr/share/zsh/site-functions/_pxar"
}
|