blob: 3eae17fb2e00c2d3b5f7966ecf55072abf5d4059 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: nl6720 <nl6720@archlinux.org>
pkgname=ps3netsrv
_wMM_version=1.47.48
pkgver=20250126
pkgrel=1
pkgdesc='PS3 Net Server (mod by aldostools)'
arch=('x86_64')
url='https://github.com/aldostools/webMAN-MOD/'
license=('GPL-3.0-or-later')
depends=('gcc-libs' 'mbedtls')
makedepends=('meson')
backup=("etc/conf.d/${pkgname}")
source=(
"https://github.com/aldostools/webMAN-MOD/releases/download/${_wMM_version}/ps3netsrv_${pkgver%a}.zip"
"${pkgname}.service"
"${pkgname}.conf"
)
sha512sums=('97cb48aa0538de524a935f02694357d9bb66af5ec697b00f328ed7161dec88fd07fa319467c9bbeec59797239e4edcccd17d6020d2b2f8d1a65bcb51e537961f'
'ce955bbaf577963244a6e96a8a8fffe037e5067321bc507fe7f71b12d8e198b5280de708dd9cffbf59d0c9a82e05bf9901dbcc8f8bc0d548b2d2c2ead7e07941'
'c81e3ef6a4bf07cd150b205793ca5a3886cf9d76c1087cc1d1325ca779628c074cfcbe8349b0bda691f61ab4f394d8594af1ed945c7207acc5712057dc5fbe59')
build() {
cd "${srcdir}/${pkgname}_${pkgver}/${pkgname}"
meson --prefix /usr --buildtype=plain build
ninja -C build
}
package() {
cd "${srcdir}/${pkgname}_${pkgver}/${pkgname}"
DESTDIR="$pkgdir" ninja -C build install
install -Dm644 "${srcdir}/${pkgname}.service" "$pkgdir/usr/lib/systemd/system/${pkgname}.service"
install -Dm644 "${srcdir}/${pkgname}.conf" "$pkgdir/etc/conf.d/${pkgname}"
install -Dm644 "${srcdir}/${pkgname}_${pkgver}/LICENSE.TXT" "$pkgdir/usr/share/licenses/${pkgname}/LICENSE.TXT"
echo 'u! ps3netsrv - "PS3 Net Server daemon"' |
install -Dm644 /dev/stdin "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
}
|