PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Sich <little_sich@tuta.io>
# Contributor: Iru Cai <mytbk920423@gmail.com>
# Contributor: Piotr Gorski <lucjan.lucjanov@gmail.com>
# Contributor: Sergej Pupykin <arch+pub@sergej.pp.ru>
# Contributor: Alexey D. <lq07829icatm@rambler.ru>

pkgname=psi-plus
pkgver=1.5.2132
pkgrel=1
pkgdesc="Psi+ is a powerful XMPP client (Qt, C++) designed for the XMPP power users (with all plugins)"
url="https://psi-im.org"
license=('GPL-2.0-or-later')
arch=('x86_64')
depends=('qt6-webengine' 'qt6-multimedia' 'qca-qt6' 'qt6-svg'
        'hunspell' 'qtkeychain-qt6' 'libotr' 'tidy' 'http-parser'
        'libusrsctp' 'libomemo-c' 'libb2')
makedepends=('cmake' 'ninja')
source=("https://github.com/psi-plus/psi-plus-snapshots/archive/${pkgver}.tar.gz")
sha256sums=('466fb31e167d6965b1bc0fda061474926bb1975b6ba93213a613c2501ffbe2a3')

build() {
  cd psi-plus-snapshots-${pkgver}
  mkdir -p build
  cd build
  cmake -G Ninja -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release \
	-DCHAT_TYPE=webengine \
	-DENABLE_PLUGINS=ON \
    -DBUILD_DEV_PLUGINS=ON \
    -DQT_DEFAULT_MAJOR_VERSION=6 \
    -DBUILD_PSIMEDIA=ON ..
  ninja
}

package() {
  cd psi-plus-snapshots-${pkgver}/build

  DESTDIR="$pkgdir" ninja install
}