blob: acf9bdfdd6cae0900d3e7eb65fc75c47c25e3485 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# $Id$
# Maintainer: Piotr Gorski <lucjan.lucjanov@gmail.com>
# Contributor: Sergej Pupykin <arch+pub@sergej.pp.ru>
# Contributor: Alexey D. <lq07829icatm@rambler.ru>
pkgname=psi-plus-git
pkgver=1.3.369.g1a3a94b7
pkgrel=1
pkgdesc="Psi+ is a powerful XMPP client (Qt, C++) designed for the XMPP power users (built with Qt 5.x)"
url="https://psi-plus.com"
license=('GPL2')
arch=('x86_64')
depends=('qt5-base' 'qt5-webengine' 'qt5-multimedia' 'qt5-x11extras' 'qca-qt5'
'libidn' 'libxss' 'qt5-svg' 'hunspell' 'qtkeychain')
makedepends=('git' 'patch' 'cmake')
provides=("psi-plus=$pkgver" "psi-plus-qt5-git=$pkgver")
conflicts=('psi-plus' 'psi-plus-qt5-git' 'psi-plus-webkit-qt5-git' 'psi-plus-webkit-git')
source=('git://github.com/psi-im/psi.git'
'psi-plus::git://github.com/psi-plus/main.git'
'git://github.com/psi-im/iris.git'
'git://github.com/psi-im/libpsi.git')
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP')
pkgver() {
cd psi
git describe --long --tags | sed 's/^v//;s/-/./g'
}
prepare() {
cd psi
# makepkg doesn't support --recursive
# so setup git modules manually
git submodule init
git config submodule.iris.url "$srcdir/iris"
git config submodule.src/libpsi.url "$srcdir/libpsi"
git submodule update
# patches from Psi+ project
for patch in "$srcdir"/psi-plus/patches/*.diff; do
echo "* Appling ${patch##*/}"
patch -p1 -i "$patch"
done
# additional icon themes
cp -a "$srcdir"/psi-plus/iconsets .
# set version
cd $srcdir/psi-plus/admin
sh psi-plus-nightly-version $srcdir/psi > $srcdir/psi/version
}
build() {
cd psi
mkdir -p build
cd build
cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release ..
make
}
package() {
cd psi/build
make DESTDIR="$pkgdir" install
}
|