blob: abfea00dfb930cd387f869fd11c4d9b6623ed494 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: tarball <bootctl@gmail.com>
pkgname=psitop
pkgver=1.0.0
pkgrel=1
pkgdesc='top for /proc/pressure'
url='https://github.com/jamespwilliams/psitop'
arch=(i686 x86_64 aarch64 riscv64)
license=(MIT)
makedepends=(go)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('d909db926bb3711027efde9c4eeb6ab2ba244a041603bb8fc940cc5a9965f025')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
mkdir -p build
go mod download
}
build() {
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS='-buildmode=pie -trimpath -mod=readonly -modcacherw'
cd "$srcdir/$pkgname-$pkgver"
go build -o $pkgname
}
package() {
cd "$srcdir/$pkgname-$pkgver"
# binary
install -Dm755 $pkgname \
"$pkgdir/usr/bin/$pkgname"
# license
install -Dm644 LICENSE \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|