summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 92649a068364392ba124180b028cc52918c12eb1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
pkgname=psp-binutils
pkgver=2.37.0
pkgrel=2
pkgdesc="binutils with PSP patch applied (psp)"
arch=(x86_64)
url="https://github.com/pspdev/binutils-gdb"
license=('GPL')
depends=('glibc' 'libelf' 'zlib' 'python')
makedepends=('git')
options=('!buildflags' '!strip' 'staticlibs')
source=(binutils-$pkgver::git+https://github.com/pspdev/binutils-gdb.git#branch=allegrex-v${pkgver})
sha256sums=('SKIP')

build()
{
  cd "$srcdir/binutils-$pkgver"
  mkdir -p build-psp && pushd build-psp
  ../configure --quiet --prefix=/usr --target=psp --enable-plugins --disable-initfini-array --disable-werror --with-system-zlib --enable-deterministic-archives
  make 
}

package()
{
  cd "$srcdir/binutils-$pkgver/build-psp"
  make install DESTDIR="$pkgdir"
  rm -r "$pkgdir"/usr/share
  rm "$pkgdir"/usr/lib/bfd-plugins/libdep.so
  rm "$pkgdir"/usr/include/gdb/jit-reader.h
}