blob: 2b69714db119001e41ec25780461cee61412e28d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: EHfive <eh5@sokka.cn>
pkgname=pulseaudio-modules-bt-git
pkgver=r107.ade461f
pkgrel=1
pkgdesc="PulseAudio Bluetooth modules with SBC, AAC, APTX, APTX-HD, Sony LDAC (A2DP codec) support"
arch=("i686" "x86_64" "arm" "armv6h" "armv7h" "aarch64")
url="https://github.com/EHfive/pulseaudio-modules-bt"
license=('GPL3')
depends=("pulseaudio>=12.0" "bluez" "bluez-libs" "sbc" "libfdk-aac.so")
makedepends=("cmake>=3.0" "libavcodec.so>=58" "libldac" "git")
optdepends=("libavcodec.so>=58: aptX Classic, aptX HD support"
"libldac: LDAC support"
"fdk-aac-free: alternative library for AAC support")
provides=("pulseaudio-bluetooth")
conflicts=("pulseaudio-bluetooth")
source=("git+https://github.com/EHfive/pulseaudio-modules-bt.git"
"git+https://github.com/pulseaudio/pulseaudio.git")
md5sums=('SKIP' 'SKIP')
pkgver() {
cd "$srcdir/pulseaudio-modules-bt"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/pulseaudio-modules-bt"
rm -r pa
ln -sf -T "../pulseaudio" "pa"
git -C pa checkout v`pkg-config libpulse --modversion|sed 's/[^0-9.]*\([0-9.]*\).*/\1/'`
}
build() {
cd "$srcdir/pulseaudio-modules-bt"
cmake \
-DCMAKE_BUILD_TYPE=Release \
.
make
}
package() {
cd "$srcdir/pulseaudio-modules-bt"
make DESTDIR="$pkgdir" install
}
|