1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
|
# Maintainer: Vincent Grande <shoober420@gmail.com>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
pkgname=(pulseaudio-nosystemd-git libpulse-nosystemd-git pulseaudio-{zeroconf,lirc,jack,bluetooth,equalizer}-nosystemd-git)
pkgdesc="A featureful, general-purpose sound server"
pkgver=13.99.1+98+g460d0c0b7
pkgrel=1
arch=(x86_64)
url="https://www.freedesktop.org/wiki/Software/PulseAudio/"
license=(GPL)
makedepends=(libasyncns libcap attr libxtst libsm libsndfile rtkit libsoxr
speexdsp tdb dbus avahi bluez bluez-libs jack sbc
lirc openssl fftw orc gtk3 webrtc-audio-processing check git meson
xmltoman gst-plugins-base-libs)
source=("git+https://gitlab.freedesktop.org/pulseaudio/pulseaudio.git")
sha256sums=('SKIP')
pkgver() {
cd pulseaudio
git describe --tags | sed 's/^v//;s/-/+/g'
}
prepare() {
cd pulseaudio
}
build() {
arch-meson pulseaudio build \
-D pulsedsp-location='/usr/\$LIB/pulseaudio' \
-D stream-restore-clear-old-devices=true \
-D udevrulesdir=/usr/lib/udev/rules.d \
-D gcov=false \
-D tests=false \
-D systemd=disabled
meson compile -C build
}
#check() {
# meson test -C build --print-errorlogs
# ninja -C build test-daemon
#}
_pick() {
local p="$1" f d; shift
for f; do
d="$srcdir/$p/${f#$pkgdir/}"
mkdir -p "$(dirname "$d")"
mv "$f" "$d"
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
done
}
package_pulseaudio-nosystemd-git() {
depends=("libpulse=$pkgver-$pkgrel" rtkit libltdl speexdsp tdb orc libsoxr
webrtc-audio-processing gst-plugins-base-libs)
optdepends=('pulseaudio-alsa: ALSA configuration (recommended)')
backup=(etc/pulse/{daemon.conf,default.pa,system.pa})
provides=(pulseaudio)
conflicts=(pulseaudio)
replaces=('pulseaudio-xen<=9.0' 'pulseaudio-gconf<=11.1')
local pulsever=$(cd pulseaudio; ./git-version-gen .tarball-version)
while [[ $pulsever = *.*.* ]]; do
pulsever=${pulsever%.*}
done
pulsever=${pulsever%%-*}
DESTDIR="$pkgdir" meson install -C build
cd "$pkgdir"
# Superseded by socket activation
sed -e '/autospawn/iautospawn = no' \
-i etc/pulse/client.conf
# Disable cork-request module, can result in e.g. media players unpausing
# when there's a Skype call incoming
sed -e 's|/usr/bin/pactl load-module module-x11-cork-request|#&|' \
-i usr/bin/start-pulseaudio-x11
# Required by qpaeq
sed -e '/Load several protocols/aload-module module-dbus-protocol' \
-i etc/pulse/default.pa
rm -r etc/dbus-1
### Split libpulse
_pick libpulse etc/pulse/client.conf
_pick libpulse usr/bin/pa{cat,ctl,dsp,mon,play,rec,record}
_pick libpulse usr/lib/libpulse{,-simple,-mainloop-glib}.so*
_pick libpulse usr/lib/{cmake,pkgconfig}
_pick libpulse usr/lib/pulseaudio/libpulse{dsp,common-*}.so
_pick libpulse usr/include
_pick libpulse usr/share/man/man1/pa{cat,ctl,dsp,mon,play,rec,record}.1
_pick libpulse usr/share/man/man5/pulse-client.conf.5
_pick libpulse usr/share/vala
### Split modules
local moddir=usr/lib/pulse-$pulsever/modules
_pick zeroconf $moddir/libavahi-wrap.so
_pick zeroconf $moddir/module-zeroconf-{publish,discover}.so
_pick zeroconf $moddir/module-raop-discover.so
_pick lirc $moddir/module-lirc.so
_pick jack $moddir/module-jack-{sink,source}.so
_pick jack $moddir/module-jackdbus-detect.so
_pick bluetooth $moddir/libbluez5-util.so
_pick bluetooth $moddir/module-bluetooth-{discover,policy}.so
_pick bluetooth $moddir/module-bluez5-{discover,device}.so
_pick equalizer $moddir/module-equalizer-sink.so
_pick equalizer usr/bin/qpaeq
}
package_libpulse-nosystemd-git() {
pkgdesc="$pkgdesc (client library)"
depends=(dbus libasyncns libcap libxtst libsm libsndfile)
provides=(libpulse{,-simple,-mainloop-glib}.so libpulse)
conflicts=(libpulse)
license=(LGPL)
backup=(etc/pulse/client.conf)
mv libpulse/* "$pkgdir"
}
package_pulseaudio-zeroconf-nosystemd-git(){
pkgdesc="Zeroconf support for PulseAudio"
provides=(pulseaudio-zeroconf)
conflicts=(pulseaudio-zeroconf)
depends=("pulseaudio=$pkgver-$pkgrel" avahi openssl)
mv zeroconf/* "$pkgdir"
}
package_pulseaudio-lirc-nosystemd-git(){
pkgdesc="IR (lirc) support for PulseAudio"
depends=("pulseaudio=$pkgver-$pkgrel" lirc)
provides=(pulseaudio-lirc)
conflicts=(pulseaudio-lirc)
mv lirc/* "$pkgdir"
}
package_pulseaudio-jack-nosystemd-git(){
pkgdesc="Jack support for PulseAudio"
depends=("pulseaudio=$pkgver-$pkgrel" jack)
provides=(pulseaudio-jack)
conflicts=(pulseaudio-jack)
mv jack/* "$pkgdir"
}
package_pulseaudio-bluetooth-nosystemd-git(){
pkgdesc="Bluetooth support for PulseAudio"
depends=("pulseaudio=$pkgver-$pkgrel" bluez bluez-libs sbc)
provides=(pulseaudio-bluetooth)
conflicts=(pulseaudio-bluetooth)
mv bluetooth/* "$pkgdir"
}
package_pulseaudio-equalizer-nosystemd-git(){
pkgdesc="Equalizer for PulseAudio"
depends=("pulseaudio=$pkgver-$pkgrel" python-{pyqt5,dbus} fftw)
provides=(pulseaudio-equalizer)
conflicts=(pulseaudio-equalizer)
mv equalizer/* "$pkgdir"
}
# vim:set sw=2 et:
|