blob: a8900781027330068f158c6c6723a222e9cace71 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Roshless <pkg@roshless.me>
# Contributor: Jelle van der Waa <jelle@dwaa.nl>
pkgname=pushgateway
pkgver=1.5.1
pkgrel=1
pkgdesc="Prometheus push acceptor for ephemeral and batch jobs."
arch=('x86_64')
url="https://github.com/prometheus/pushgateway"
license=('Apache')
depends=('glibc')
makedepends=('go' 'git')
source=("https://github.com/prometheus/pushgateway/archive/v${pkgver}.tar.gz"
"pushgateway.service")
build() {
cd $pkgname-$pkgver
LDFLAGS="-extldflags $LDFLAGS \
-X github.com/prometheus/common/version.Version=$pkgver \
-X github.com/prometheus/common/version.Revision=$pkgver \
-X github.com/prometheus/common/version.Branch=tarball \
-X github.com/prometheus/common/version.BuildUser=someone@builder \
-X github.com/prometheus/common/version.BuildDate=$(date -d@"$SOURCE_DATE_EPOCH" +%Y%m%d-%H:%M:%S)"
go build \
-trimpath \
-buildmode=pie \
-mod=readonly \
-modcacherw \
-ldflags "-linkmode external $LDFLAGS" \
.
}
check() {
cd $pkgname-$pkgver
go test ./...
}
package() {
install -Dm644 $pkgname.service -t "$pkgdir/usr/lib/systemd/system/"
cd $pkgname-$pkgver
install -Dm755 $pkgname -t "$pkgdir/usr/bin/"
}
sha512sums=('01ebcdb85f059c330195f37f9466e2042311d8196948881f07d53f1ac4c7daedf343c14856f51db274df00b652b09eb52c735f04f774baf66559697864e1f93b'
'baf8f41a9643b7c8e9bdf59a38c6275df8861ed4c033de3ef3dd80ed8687d001724f43cad968d5f6c2d4c3541aa4d8b84d7c3a266f149e780c7168074b37f711')
|