PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

# Maintainer: Nathan Robinson <nrobinson2000 at me dot com>

pkgname=pvr-tex-tool-bin
pkgver=2020.2
_versionstr='2020_R2'
pkgrel=4

pkgdesc="A comprehensive texture processing and compression tool with support for PVR textures."
url="https://www.imaginationtech.com/developers/powervr-sdk-tools/pvrtextool/"

arch=('x86_64')
options=('!strip')
license=('custom')

source=("install.run::https://cdn.imgtec.com/sdk/OFFLINE/PVRTexToolSetup-${_versionstr}.run-x64"
"LICENSE.html::https://www.imaginationtech.com/developers/powervr-sdk-tools/powervr-sdk-software-eula/"
"PVRTexTool.desktop")

sha256sums=('5f6bea49943e52d2f59541efca0bce8c1f841f9a5baf1a193c94cd0e1fcb4a31'
            '251a7012447f80a9cc1459028e12fb09794a5d003482e0d7dd3580a52ab5c686'
            '993d3b02d822ad2b87feae194740d1eda4293375d8e82c9455cc5ec5dcdb1444')

# discovered with namcap(1)
depends=(qt5-base libxcursor dbus-x11 libxrandr freetype2 hicolor-icon-theme)

package() {
_srcname=PVRTexTool

# Run installer
chmod +x "${srcdir}/install.run" 
"${srcdir}/install.run" --prefix "${srcdir}" --mode unattended

# Install license
install -Dm644 LICENSE.html "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.html"

# Install documentation
mkdir -p "${pkgdir}/usr/share/doc/${pkgname}"
mv ${srcdir}/${_srcname}/Documentation/* "${pkgdir}/usr/share/doc/${pkgname}"

# Install library
mkdir -p "${pkgdir}/usr/include"
mkdir -p "${pkgdir}/usr/lib"
mv ${srcdir}/${_srcname}/Library/Include/* "${pkgdir}/usr/include"
mv ${srcdir}/${_srcname}/Library/Linux_x86_64/* "${pkgdir}/usr/lib"

# Install CLI binaries
install -D "${srcdir}/${_srcname}/CLI/Linux_x86_64/compare" "${pkgdir}/usr/bin/pvr-compare"
install -D "${srcdir}/${_srcname}/CLI/Linux_x86_64/PVRTexToolCLI" "${pkgdir}/usr/bin/pvr-tex-tool"

# Install GUI application
mkdir -p "${pkgdir}/usr/share/${pkgname}"
mv ${srcdir}/${_srcname}/GUI/Linux_x86_64/* "${pkgdir}/usr/share/${pkgname}"
ln -s "/usr/share/${pkgname}/PVRTexToolGUI" "${pkgdir}/usr/bin/pvr-tex-tool-gui"

# Delete .run file (only pacman should be allowed to perform updates)
rm "${pkgdir}/usr/share/${pkgname}/autoupdate-linux-x64.run"

# Copy icons
pushd "${pkgdir}/usr/share/${pkgname}/Icons" > /dev/null
for _image in *.png; do
_size="${_image//[^0-9]/}"
install -D "${_image}" "${pkgdir}/usr/share/icons/hicolor/${_size}x${_size}/apps/PVRTexTool.png"
done
popd > /dev/null

# Create desktop entry
install -D "PVRTexTool.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}