blob: 2d82e53b3a61d5c5770885eb81039aa9c022a540 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
pkgname=pwndbg-git
pkgver=2026.02.18.r1.g5eb91f4
pkgrel=1
pkgdesc='Makes debugging with GDB suck less'
url='https://github.com/pwndbg/pwndbg'
arch=(any)
license=(MIT)
depends=(
debuginfod
gdb
ipython
python
python-capstone
python-capstone6pwndbg
python-niche-elf
python-psutil
python-pt
python-ptrace
python-pwntools
python-pycparser
python-pyelftools
python-pygments
python-requests
python-rich
python-setuptools
python-sortedcontainers
python-tabulate
python-typing_extensions
python-unicorn
# TODO:
# decomp2dbg
which
)
makedepends=(
git
python-build
python-hatchling
python-installer
python-poetry-core
python-wheel
)
optdepends=(
'checksec: checksec command support'
'ropper: ropper command support'
'ropgadget: ropgadget command support'
'radare2: radare2 command support'
'rizin: rizin command support'
'one_gadget: command to find ROP one_gadget'
)
provides=(pwndbg)
conflicts=(pwndbg)
source=(${pkgname}::git+https://github.com/pwndbg/pwndbg)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd ${pkgname}
rm -rf profiling
}
build() {
cd ${pkgname}
python -m compileall *.py
python -O -m compileall *.py
python -m build --wheel --no-isolation
}
package() {
cd ${pkgname}
python -m installer --destdir="${pkgdir}" dist/*.whl
install -d "${pkgdir}/usr/share/pwndbg"
cp -r *.py __pycache__ "${pkgdir}/usr/share/pwndbg"
install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim: ts=2 sw=2 et:
|