blob: d88d35f08eebaa391708e58c4e689df410149a79 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
# Contributor: Dave Reisner <d@falconindy.com>
_pkgname=pyalpm
pkgname=$_pkgname-git
pkgver=0.8.4.r8.g06fa0ea
pkgrel=1
pkgdesc="Libalpm bindings for Python 3 (Git version)"
arch=('x86_64')
url="https://git.archlinux.org/pyalpm.git/"
license=('GPL3')
depends=('python>=3.6' 'pacman>=5')
makedepends=('git')
checkdepends=('python-nose')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=('git+https://git.archlinux.org/pyalpm.git')
sha256sums=('SKIP')
pkgver() {
cd $_pkgname
( set -o pipefail
git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
)
}
build() {
cd $_pkgname
python setup.py build
}
check() {
cd $_pkgname
PYTHONPATH="$(ls -d build/lib.linux-$CARCH-*)" nosetests -v tests
}
package() {
cd $_pkgname
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
}
|