blob: 813a409c9bd2568bc4a9845470dfb7b74f8d4fab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Contrubutor: Ionut Biru <ibiru@archlinux.org>
# Maintainer: wangjiezhe <wangjiezhe AT yandex DOT com>
_pkgbase=pygobject
pkgbase=pygobject-patched
pkgname=(python-gobject-patched python2-gobject-patched pygobject-devel-patched)
pkgver=3.24.1
pkgrel=1
pkgdesc="Python Bindings for GLib/GObject/GIO/GTK+"
url="https://wiki.gnome.org/Projects/PyGObject"
arch=(i686 x86_64)
license=(LGPL)
depends=(gobject-introspection-runtime)
makedepends=(python-cairo-git python2-cairo gobject-introspection gnome-common)
optdepends=('cairo: Cairo bindings')
source=("https://download.gnome.org/sources/${_pkgbase}/${pkgver:0:4}/${_pkgbase}-${pkgver}.tar.xz"
"01_cairo_region.patch")
sha256sums=('a628a95aa0909e13fb08230b1b98fc48adef10b220932f76d62f6821b3fdbffd'
'70d890c4f56cb677a386dcd5cfe554957c200802b788e582b22b09ba49a423a2')
prepare() {
mkdir -p build-py{2,3} devel
cd ${_pkgbase}-${pkgver}
patch -Np1 -i "$srcdir/01_cairo_region.patch"
}
_build() (
cd build-py$1
../${_pkgbase}-${pkgver}/configure --prefix=/usr --with-python=/usr/bin/python$1
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
)
build() {
_build 2
_build 3
}
package_python-gobject-patched() {
depends=("pygobject-devel=$pkgver" python)
provides=("python-gobject=$pkgver")
conflicts=('python-gobject')
cd build-py3
make DESTDIR="$pkgdir" install
mv "$pkgdir"/usr/{include,lib/pkgconfig} "$srcdir/devel"
}
package_python2-gobject-patched() {
pkgdesc="${pkgdesc/Python/Python2}"
depends=("pygobject-devel=$pkgver" python2)
provides=("python2-gobject=$pkgver")
conflicts=('python2-gobject')
cd build-py2
make DESTDIR="$pkgdir" install
python2 -m compileall "$pkgdir"/usr/lib/python2.7/site-packages/gi
rm -r "$pkgdir"/usr/{include,lib/pkgconfig}
}
package_pygobject-devel-patched() {
pkgdesc="Common development files for pygobject"
provides=("pygobject-devel=$pkgver")
conflicts=("pygobject-devel")
cd devel
mkdir -p "$pkgdir/usr/lib"
mv include "$pkgdir/usr/"
mv pkgconfig "$pkgdir/usr/lib/"
}
|