blob: feb1283c5e3d145cf714e195be72810bc45c6cfd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
pkgname=pyside2
_qtver=5.13.0
pkgver=${_qtver/-/}
pkgrel=2
arch=(x86_64)
url='https://www.qt.io'
license=(LGPL)
pkgdesc='Enables the use of Qt5 APIs in Python applications'
depends=(python-shiboken2 qt5-base)
makedepends=(shiboken2 cmake
qt5-multimedia qt5-tools qt5-sensors qt5-charts qt5-webengine qt5-datavis3d
qt5-websockets qt5-speech qt5-3d qt5-svg qt5-script qt5-scxml qt5-x11extras qt5-remoteobjects)
optdepends=('qt5-svg: QtSvg bindings'
'qt5-script: QtScript bindings'
'qt5-speech: QtTextToSpeech bindings'
'qt5-websockets: QtWebSockets bindings'
'qt5-webengine: QtWebEngine bindings'
'qt5-datavis3d: QtDataVisualization bindings'
'qt5-scxml: QtScxml bindings'
'qt5-sensors: QtSensors bindings'
'qt5-3d: Qt3D bindings'
'qt5-x11extras: QtX11Extras bindings'
'qt5-charts: QtCharts bindings'
'qt5-tools: QtHelp bindings'
'qt5-remoteobjects: QtRemoteObjects bindings')
groups=(qt qt5)
conflicts=(python-pyside2)
provides=(python-pyside2)
replaces=(python-pyside2)
_pkgfqn=pyside-setup-everywhere-src-${_qtver}
source=("https://download.qt.io/official_releases/QtForPython/pyside2/PySide2-$pkgver-src/${_pkgfqn}.tar.xz"
qcoreapplication-crash.patch::"https://code.qt.io/cgit/pyside/pyside-setup.git/patch/?id=80a6f91c")
sha256sums=('8e47e778a6c8ee86e9bc7dbf56371cf607e9f3c1a03a7d6df9e34f8dba555782'
'7d36bfc604f4759f593e8d599e04e9ef713b35b3e0c373c12868b32913564303')
prepare() {
mkdir -p build
cd $_pkgfqn
patch -Rp1 -i ../qcoreapplication-crash.patch # Revert commit that makes QCoreApplication import crash
}
build() {
cd build
cmake ../${_pkgfqn}/sources/pyside2 \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_TESTS=OFF \
-DPYTHON_EXECUTABLE=/usr/bin/python
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|