PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Gordian Edenhofer <gordian.edenhofer@gmail.com>

pkgname=python-acme-git
_reponame="certbot"
pkgver=2.6.0.r10.g2d8a274eb
pkgrel=1
pkgdesc="ACME protocol implementation for Python"
arch=('any')
license=('Apache')
url="https://github.com/certbot/${_reponame}"
depends=('python-setuptools' 'python-cryptography' 'python-josepy' 'python-pyopenssl'
	'python-pyrfc3339' 'python-pytz' 'python-requests' 'python-requests-toolbelt')
makedepends=('git')
provides=("python-acme=${pkgver}")
conflicts=("python-acme")
source=("${_reponame}"::"git+https://github.com/certbot/${_reponame}")
sha512sums=('SKIP')

pkgver() {
	cd "${srcdir}/${_reponame}"
	( set -o pipefail
	git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' \
	|| printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

build() {
	cd "${srcdir}/${_reponame}/acme"
	python setup.py clean
	rm -rf build dist
	python setup.py build
}

package_python-acme-git() {
	cd "${srcdir}/${_reponame}/acme"
	python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}