blob: 1bf08d2d576416758398b3435130d23799e5132b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: giver <ryan01234keroro56789@gmail.com>
_pyname=angr
pkgname=python-${_pyname}
pkgver=9.2.81
pkgrel=3
pkgdesc='A powerful and user-friendly binary analysis platform'
url='https://github.com/angr/angr'
license=('BSD')
arch=('any')
depends=(
'python'
'python-cppheaderparser'
'python-gitpython'
'python-ailment'
'python-archinfo'
'python-cachetools'
'python-capstone'
'python-cffi'
'python-claripy'
'python-cle'
'python-dpkt'
'python-itanium_demangler'
'python-mulpyplexer'
'python-nampa'
'python-networkx'
'python-protobuf'
'python-psutil'
'python-pycparser'
'python-pyvex'
'python-rich'
'python-rpyc'
'python-sortedcontainers'
'python-sympy'
'python-unicorn'
)
makedepends=(
'gcc'
'make'
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('fb4d8beb41804d700a10d99583f72dc3443ac21686d0e3f7314f3aaa1b69f33fca88585865e27730102bf1ca7e2301d4bbce2e65a314ad6b9875c652b8638af3')
b2sums=('bdaf94faffde85c1fc16b3a145f72e58bbb406e2953c08601abd3b42cb5693ac6d47c17f85b5762d8bdbb3e0689d79600b592fbf7fb1ba373101ea196a5ed8d4')
prepare() {
# we don't support version pinning
sed -e 's/==/>=/g' -i $_pyname-$pkgver/{setup.cfg,pyproject.toml}
# we don't support post-release and developmental-release
sed -e 's/\.\(post\|dev\)[0-9]*//g' -i $_pyname-$pkgver/{setup.cfg,pyproject.toml}
}
build() {
cd ${_pyname}-${pkgver}
python -m build --wheel --no-isolation
}
package() {
cd ${_pyname}-${pkgver}
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|