PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Daniel Vrátil <me@dvratil.cz>

_name=aqtinstall
pkgname=python-aqtinstall
pkgver=3.1.6
pkgrel=1
pkgdesc="Another unofficial Qt installer"
arch=(any)
url="https://github.com/miurahr/aqtinstall"
license=('MIT')
depends=(python python-defusedxml python-requests python-beautifulsoup4
         python-semantic-version python-texttable python-patch
         python-py7zr python-humanize)
makedepends=(python-twine python-build python-installer python-wheel python-setuptools-scm)
checkdepends=(python-pytest python-pytest-socket)
source=($pkgname::git+${url}.git#tag=v${pkgver})
sha512sums=('SKIP')

build() {
    cd ${pkgname}
    python -m build --wheel --no-isolation
}

check() {
    cd ${pkgname}
    python -m twine check dist/*
}

package() {
    cd ${pkgname}
    python -m installer --destdir="${pkgdir}" dist/*.whl
    install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}