blob: 85b9e08559c28a0abb95478ec65d9882fdffd795 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Contributor: Miguel de Val-Borro <miguel . deval @ gmail . com>
pkgname=python-astroquery-git
_gitname=astroquery
pkgver=0.4.11.r310.gc9f253895
pkgrel=1
pkgdesc="Set of tools for querying astronomical web forms and databases"
arch=('any')
url="https://astroquery.readthedocs.org/en/latest/"
license=('BSD-3-Clause')
depends=(
'python-astropy'
'python-numpy'
'python-requests'
'python-keyring'
'python-beautifulsoup4'
'python-html5lib'
'python-pyvo'
)
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}")
makedepends=(
'git'
'python-setuptools'
'python-setuptools-scm'
'python-build'
'python-installer'
'python-wheel'
)
optdepends=(
'python-astropy-healpix: for full functionality of the alma module'
'python-regions: for full functionality of the alma module'
'python-boto3: for full functionality of the mast module'
)
source=("git+https://github.com/astropy/astroquery")
md5sums=(SKIP)
pkgver() {
cd $_gitname
git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./g'
}
build() {
cd $_gitname
python -m build --wheel --no-isolation
}
package() {
cd $_gitname
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" LICENSE.rst licenses/*
python -m installer --destdir="$pkgdir" dist/*.whl
}
# vim: set ts=2 sw=2 et:
|