blob: bdff8d0d1423610bc8206e01fca2da6fac018820 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Astro Benzene <universebenzene at sina dot com>
pkgbase=python-astroscrappy
pkgname=('python-astroscrappy' 'python-astroscrappy-doc')
pkgver=1.0.5
pkgrel=4
pkgdesc="Speedy Cosmic Ray Annihilation Package in Python"
arch=('i686' 'x86_64')
url="https://github.com/astropy/astroscrappy"
license=('BSD')
makedepends=('cython>=0.21' 'python-astropy' 'python-astropy-helpers' 'python-sphinx' 'python-matplotlib')
checkdepends=('python-pytest-astropy')
source=("https://files.pythonhosted.org/packages/source/a/astroscrappy/astroscrappy-${pkgver}.tar.gz")
md5sums=('e7ec5d829191226e6092b08e1d8f4cd4')
prepare() {
cd ${srcdir}/astroscrappy-${pkgver}
sed -i -e '/auto_use/s/True/False/' setup.cfg
}
build () {
cd ${srcdir}/astroscrappy-${pkgver}
python setup.py build --use-system-libraries --offline
msg "Building Docs"
python setup.py build_docs
}
check(){
cd ${srcdir}/astroscrappy-${pkgver}
python setup.py test
}
package_python-astroscrappy() {
depends=('python' 'python-numpy' 'python-astropy' 'cython>=0.21')
optdepends=('python-astroscrappy-doc: Documentation for Astro-SCRAPPY')
cd ${srcdir}/astroscrappy-${pkgver}
install -d -m755 "${pkgdir}/usr/share/licenses/${pkgname}/"
install -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" licenses/*
install -D -m644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
python setup.py install --root=${pkgdir} --prefix=/usr --optimize=1 --use-system-libraries --offline
}
package_python-astroscrappy-doc() {
pkgdesc="Documentation for Astro-SCRAPPY"
cd ${srcdir}/astroscrappy-${pkgver}/build/sphinx
install -d -m755 "${pkgdir}/usr/share/doc/${pkgbase}"
cp -a html "${pkgdir}/usr/share/doc/${pkgbase}"
}
|