blob: 8532f4f16e132c6ef79f1afed8d06af8199c2206 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# -*- sh -*-
# Maintainer: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x ka-i@p-u.l)>
pkgname='python-atproto-git'
_pkgname="${pkgname/-git/}"
_srcname="${_pkgname/python-/}"
pkgver=0.0.62.r1.gceaa1f1
pkgrel=1
pkgdesc='The AT Protocol (Bluesky) SDK for Python (development version)'
arch=('any')
url='https://github.com/MarshalX/atproto'
license=(
'MIT' # SPDX-License-Identifier: MIT (main package)
'CC0-1.0' # SPDX-License-Identifier: CC0-1.0 (examples)
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-poetry-dynamic-versioning'
'python-wheel'
)
depends=(
'python>=3.8'
'python-click'
'python-cryptography'
'python-dnspython'
'python-httpx'
'python-libipld'
'python-pydantic'
'python-typing_extensions'
'python-websockets'
)
source=("git+$url.git")
provides=("$_pkgname"{,_{cli,client,codegen,core,crypto,firehose,identity,lexicon,server}})
conflicts=("${provides[@]}")
sha256sums=('SKIP')
pkgver() {
cd "$_srcname"
git describe --tags --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_srcname"
python -m build --wheel --no-isolation
}
package() {
cd "$_srcname"
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
install -vDm0644 -t "$pkgdir/usr/share/doc/$pkgname" \
{CHANGES,README,SECURITY}.md
cp -vfax examples "$pkgdir/usr/share/doc/"
}
# eof
|