summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3711579e3837eaeec77d40b78a53719d9b6a3be5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: KokaKiwi <kokakiwi+aur@kokakiwi.net>

_pkgname=autokernel
pkgname="python-${_pkgname}-git"
pkgver=v0.9.6.r0.g43bbe35
pkgrel=1
pkgdesc="A tool to autodetect and manage kernel configuration options"
arch=('any')
url="https://autokernel.oddlama.org/"
license=('MIT')
depends=('python'
         'python-kconfiglib' 'python-lark-parser' 'python-dateutil'
         'python-requests' 'python-sympy')
makedepends=('python-setuptools')
source=("${pkgname}::git+https://github.com/oddlama/autokernel.git")
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname}"

  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${pkgname}"

  python setup.py build
}

package() {
  cd "${pkgname}"

  python setup.py install --root="${pkgdir}" --optimize=1
  install -Dm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}