blob: 6714ae9345262499474cea82522d88d0eb89a17c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: Daniel M. Capella <polycitizen@gmail.com>
# Maintainer: James Zhu <jameszhu@berkeley.edu>
pkgname=python-black
pkgver=18.6b4
pkgrel=1
pkgdesc='The uncompromising Python code formatter'
arch=('any')
url=https://github.com/ambv/black
license=('MIT')
depends=('python' 'python-appdirs' 'python-attrs' 'python-click' 'python-toml')
makedepends=('python-setuptools')
source=("https://files.pythonhosted.org/packages/source/b/black/black-$pkgver.tar.gz")
sha512sums=('6bacac0de9c8b596b5570d454ace89b1e7a27f6adb8b731e00fe605102067d04ad80db73ed87a8198a219c4ec8a2b2681d088d0b2da71437b817dec13bcaa23e')
build() {
cd black-$pkgver
python setup.py build
}
check() {
cd black-$pkgver
python -m unittest tests/test_black.py
}
package() {
cd black-$pkgver
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/black/LICENSE
}
# vim:set ts=2 sw=2 et:
|