blob: 3a7432fec2af057135a56a86ae62c56ff3add9bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Blair Bonnett <blair dot bonnett at gmail dot com>
pkgname=python-blackdoc
_pypi=blackdoc
pkgdesc='Run Black on documentation code snippets'
pkgver=0.3.9
pkgrel=1
url='https://github.com/keewis/blackdoc'
license=('MIT')
arch=('any')
depends=('python-black' 'python-more-itertools' 'python-rich')
optdepends=(
'ipython: for working with .ipynb files'
'python-tokenize-rt: for working with .ipynb files'
)
makedepends=(
'python-build' 'python-installer' 'python-setuptools' 'python-setuptools-scm'
'python-wheel'
)
checkdepends=('python-pytest')
source=(
"https://files.pythonhosted.org/packages/source/${_pypi::1}/$_pypi/$_pypi-$pkgver.tar.gz"
)
sha256sums=(
'b1da5ca93550081fc3f1b34bfdc731431ee74c378ea63abb31771a222ef5d053'
)
build() {
cd "$_pypi-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "$_pypi-$pkgver"
PYTHONPATH=$PWD/build/lib pytest -v
}
package() {
cd "$_pypi-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|