blob: 7b0641aa2f81aa06d2ab222d25f8cb74289c3a22 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Guillaume Horel <guillaume.horel@gmail.com>
# Contributor: William Turner <willtur.will@gmail.com>
_pyname=booleanOperations
pkgname=python-${_pyname,,}
pkgver=0.9.0
pkgrel=2
pkgdesc='Boolean operations on paths'
arch=(any)
url="https://github.com/typemytype/$_pyname"
license=(MIT)
_pydeps=(pyclipper
fonttools)
depends=(python
"${_pydeps[@]/#/python-}")
checkdepends=(python-defcon
python-fontpens
python-pytest)
makedepends=(python-setuptools-scm)
_archive="$_pyname-$pkgver"
source=("https://files.pythonhosted.org/packages/source/${_pyname::1}/$_pyname/$_archive.zip")
sha256sums=('8cfa821c32ad374fa120d6b2e0b444ebeac57c91e6631528645fa19ac2a281b8')
prepare() {
cd "$_archive"
# Upstream PR: https://github.com/typemytype/booleanOperations/pull/63
sed -i -e '/wheel$/d' setup.cfg
}
build() {
cd "$_archive"
export PYTHONHASHSEED=0
python setup.py build
}
check() {
cd "$_archive"
PYTHONPATH=Lib pytest tests
}
package() {
cd "$_archive"
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
}
|