blob: 18ba0fc067a32da3fbcb6f2213f783b57507e550 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
pkgname=python-buildozer-git
_pkgname=buildozer
pkgver=1.5.0.131.g91ce81b
pkgrel=1
pkgdesc="Generic Python packager for Android / iOS and Desktop (git version)"
arch=('any')
url="https://github.com/kivy/buildozer"
license=('MIT')
depends=(
'python'
'python-colorama'
'python-pexpect'
'python-virtualenv'
'python-sh'
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-wheel'
'python-setuptools'
)
optdepends=('python-paramiko: remote builds')
provides=('python-buildozer')
conflicts=('python-buildozer')
options=(!emptydirs)
source=("git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/${_pkgname}"
git describe --tags --long --always | sed 's/^v//;s/-/./g'
}
build() {
cd "$srcdir/${_pkgname}"
python -m build --wheel --no-isolation
}
package() {
cd "$srcdir/${_pkgname}"
python -m installer --destdir="$pkgdir" dist/*.whl
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|