blob: 87a9fdc95f273249d94e51fe95e0c1c9fab85804 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- sh -*-
pkgname='python-can_ada-git'
_pkgname="${pkgname/-git/}"
_srcname="${_pkgname/python-/}"
_srcdir="${_srcname}"
pkgver=1.2.0.r0.g378192b
pkgrel=2
pkgdesc='Python bindings for Ada, a fast and WHATWG spec-compliant URL parser (built from latest commit)'
arch=('aarch64' 'x86_64')
url="https://github.com/TkTech/$_srcname"
license=('MIT') # SPDX-License-Identifier: MIT
makedepends=(
'git'
'pybind11'
'python-build'
'python-installer'
'python-wheel'
)
depends=(
'gcc-libs'
'glibc'
'python'
)
source=("git+$url.git")
provides=("$_pkgname")
conflicts=("$_pkgname")
sha256sums=('SKIP')
pkgver() {
cd "$_srcdir"
git describe --long --tags \
| sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_srcdir"
# RFC-0023
# 🔗 https://rfc.archlinux.page/0023-pack-relative-relocs/
#
# ld(1) says: “Supported for i386 and x86-64.”
case "${CARCH:-unknown}" in
'x86_64' | 'i386' )
export LDFLAGS="$LDFLAGS -Wl,-z,pack-relative-relocs"
;;
* ) : pass ;;
esac
python -m build --wheel --no-isolation
}
package() {
cd "$_srcdir"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# eof
|