PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Maik93 <michael.mugnai@gmail.com>
# Contributor: Ethan Zonca <e@ethanzonca.com>

pkgname=python-cantools
_gitname=cantools
provides=('python-cantools')
conflicts=('python-cantools')
pkgdesc="Python CAN bus tools in Python 3"
url="https://github.com/eerimoq/cantools"
pkgver=39.2.0
pkgrel=1
arch=('i686' 'x86_64' 'armv7h')
license=('GPL3')
makedepends=('python-build' 'python-installer' 'python-wheel')
depends=(
    'python-bitstruct>=6.0.0'
    'python-can>=2.2.0'
    'python-textparser>=0.21.1'
    'python-diskcache'
    'python-argparse-addons'
)
optdepends=('python-matplotlib: plot decoded messages')

source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
md5sums=('42d915595e17133baefdfd5fd0d6613f')

build() {
	cd "$srcdir/$_gitname-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
	cd "$srcdir/$_gitname-$pkgver"
	python -m installer --destdir="$pkgdir" dist/*.whl
    install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/LICENSE
}