PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Maintainer: zhullyb <zhullyb@outlook.com>
# Contributor: BigfootACA <bigfoot@classfun.cn>

_pyname=castellan
pkgname=python-$_pyname
pkgver=3.7.1
pkgrel=1
pkgdesc="Generic Key Manager interface for OpenStack"
arch=(any)
url="https://opendev.org/openstack/castellan"
license=(Apache)
depends=(
	python
	python-pbr
	python-cryptography
	python-barbicanclient
	python-oslo-config
	python-oslo-context
	python-oslo-i18n
	python-oslo-log
	python-oslo-utils
	python-stevedore
	python-keystoneauth1
	python-requests
)
checkdepends=(
	python-hacking
	python-pyflakes
	python-coverage
	python-barbicanclient
	python-subunit
	python-oslotest
	python-stestr
	python-fixtures
	python-testscenarios
	python-testtools
	bandit
	python-pifpaf
	python-pre-commit
)
makedepends=(
	python
	python-pbr
)
source=(https://pypi.io/packages/source/${_pyname::1}/$_pyname/$_pyname-$pkgver.tar.gz)
md5sums=('1d5f21a1d503a2213559aca139c282fc')
sha256sums=('c6ea28b41e4c75fbb1945145b2516f6f9750f8405d2b01efc7c5681286137447')
sha512sums=('f218a55e1e536a22722bbaa66c50eb80efdb39be728d7852d03b6c30cc6587de055fb68cc2add10f68afa950658f03fe8495f792fd37e5d29caa2687e0753f3d')

export PBR_VERSION=$pkgver

build(){
	pushd $_pyname-$pkgver
	python setup.py build
}

check(){
	pushd $_pyname-$pkgver
	stestr run
}

package(){
	cd $_pyname-$pkgver
	python setup.py install --root "$pkgdir" --optimize=1
	install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}