PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-chameleon
pkgname=('python-chameleon' 'python2-chameleon')
pkgver=2.25
pkgrel=1
pkgdesc="Fast HTML/XML Template Compiler"
arch=('any')
license=('custom:BSD' 'ZPL')
url="http://www.pagetemplates.org/"
makedepends=('python-setuptools' 'python2-setuptools' 'git')
source=("git+https://github.com/malthe/chameleon.git#tag=$pkgver")
sha512sums=('SKIP')

prepare() {
  cp -a chameleon{,-py2}
}

build() {
  cd "$srcdir"/chameleon
  python setup.py build

  cd "$srcdir"/chameleon-py2
  python2 setup.py build
}

check() {
  cd "$srcdir"/chameleon
  python setup.py test

  cd "$srcdir"/chameleon-py2
  python2 setup.py test
}

package_python-chameleon() {
  depends=('python')

  cd chameleon
  python setup.py install --root="$pkgdir" --optimize=1
  install -D -m644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
}

package_python2-chameleon() {
  depends=('python2')

  cd chameleon-py2
  python2 setup.py install --root="$pkgdir" --optimize=1
  install -D -m644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
}