PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

# Maintainer: Astro Benzene <universebenzene at sina dot com>
pkgbase=python-ci_watson
_pyname=${pkgbase#python-}
pkgname=("python-${_pyname}" "python-${_pyname}-doc")
pkgver=0.9.0
pkgrel=1
pkgdesc="CI helper for STScI Jenkins"
arch=('any')
url="https://ci_watson.readthedocs.io"
license=('BSD-3-Clause')
makedepends=('python-setuptools-scm'
             'python-build'
             'python-installer'
             'python-sphinx-automodapi'
             'python-sphinx-copybutton'
             'python-sphinx_design'
             'python-pydata-sphinx-theme'
             'python-numpydoc'
             'python-crds'
             'python-pytest'
             'python-readchar'
             'python-colorama')  # wheel required by new setuptools
checkdepends=('python-pytest-astropy-header') # crds already in makedepends
source=("https://github.com/spacetelescope/${_pyname}/archive/${pkgver}.tar.gz")
md5sums=('d50f39589b33f767790cc3bf1979dea4')

get_pyinfo() {
    [[ $1 == "site" ]] && python -c "import site; print(site.getsitepackages()[0])" || \
        python -c "import sys; print('$1'.join(map(str, sys.version_info[:2])))"
}

prepare() {
    export SETUPTOOLS_SCM_PRETEND_VERSION=${pkgver}
}

build() {
    cd ${srcdir}/${_pyname}-${pkgver}
    python -m build --wheel --no-isolation

    msg "Building Docs"
    python -m installer --destdir=tmp_install dist/*.whl
    cp -r ${_pyname}/scripts tmp_install/$(get_pyinfo site)/${_pyname}
#   ln -rs ${srcdir}/${_pyname}-${pkgver}/${_pyname/-/_}*egg-info \
#       build/lib/${_pyname/-/_}-${pkgver}-py$(get_pyver .).egg-info
    PATH="${srcdir}/${_pyname}-${pkgver}/tmp_install/usr/bin:${PATH}" \
        PYTHONPATH="${srcdir}/${_pyname}-${pkgver}/tmp_install/$(get_pyinfo site)" make -C docs html
}

check() {
    cd ${srcdir}/${_pyname}-${pkgver}
    # Variable needs for inputs_root
#   PYTHONPATH="build/lib" pytest -vv -l -ra --color=yes -o console_output_style=count # || warning "Tests failed" # -vv -l -ra --color=yes -o console_output_style=count #
    PYTHONPATH="${srcdir}/${_pyname}-${pkgver}/tmp_install/$(get_pyinfo site)" \
        pytest || warning "Tests failed" # -vv -l -ra --color=yes -o console_output_style=count #
}

package_python-ci_watson() {
    depends=('python>=3.9' 'python-pytest>=6' 'python-crds' 'python-readchar>=3.0' 'python-colorama>=0.4.1') # requests <- crds
    optdepends=('python-astropy>=6'
                'python-ci_watson-doc: Documentation for CI Watson')
    cd ${srcdir}/${_pyname}-${pkgver}

    install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE.md
    install -D -m644 -t "${pkgdir}/usr/share/doc/${pkgname}" README.md
    python -m installer --destdir="${pkgdir}" dist/*.whl
    cp -a ${_pyname}/scripts ${pkgdir}/$(get_pyinfo site)/${_pyname}
}

package_python-ci_watson-doc() {
    pkgdesc="Documentation for CI Watson"
    cd ${srcdir}/${_pyname}-${pkgver}/docs/build

    install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}" ../../LICENSE.md
    install -d -m755 "${pkgdir}/usr/share/doc/${pkgbase}"
    cp -a html "${pkgdir}/usr/share/doc/${pkgbase}"
}