PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Alex Forencich <alex@alexforencich.com>
pkgname=python-cocotbext-uart-git
pkgver=0.1.0.r0.g4f3a8f2
pkgrel=1
pkgdesc="UART modules for cocotb"
arch=('any')
url="https://github.com/alexforencich/cocotbext-uart"
license=('MIT')
depends=('python-cocotb')
provides=('python-cocotbext-uart')
conflicts=('python-cocotbext-uart')
makedepends=('git' 'python-setuptools')

_gitroot='https://github.com/alexforencich/cocotbext-uart.git'
_gitname='cocotbext-uart'

source=("$_gitname::git+$_gitroot")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/$_gitname"
    git describe --tags --long | sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/$_gitname"
    python setup.py build
}

package() {
    cd "$srcdir/$_gitname"
    python setup.py install --skip-build --prefix=/usr --root="$pkgdir/" --optimize=1
    install -m 644 -D ./LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/LICENSE
}