blob: 7ebd453617ba68c1cde5defaea699bc9a248ea17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer:
_module="cxxheaderparser"
_pkgname="python-$_module"
pkgname="$_pkgname-git"
pkgver=1.6.1.r0.g3abac6d
pkgrel=1
pkgdesc="Parse C++ header files and generate a data structure representing the class"
url="https://github.com/robotpy/cxxheaderparser"
license=('BSD-3-Clause')
arch=('any')
depends=(
'python'
)
makedepends=(
'git'
'python-build'
'python-hatch-vcs'
'python-hatchling'
'python-installer'
'python-wheel'
)
provides=("$_pkgname=${pkgver%.g*}")
conflicts=("$_pkgname")
_pkgsrc="$_module"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgsrc"
git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
| sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}
build() {
cd "$_pkgsrc"
python -m build --wheel --no-isolation --skip-dependency-check
}
package() {
cd "$_pkgsrc"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|