blob: 0e14e66970ab303af3a1335d8a1944020d0cacd2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=python-cyclonedx-lib
_gitpkgname=cyclonedx-python-lib
pkgver=4.2.2
pkgrel=1
pkgdesc='Library for producing CycloneDX SBOM (Software Bill of Materials) files'
arch=('any')
url='https://github.com/CycloneDX/cyclonedx-python-lib'
license=('Apache')
depends=(
'python-license-expression'
'python-packageurl'
'python-py-serializable'
'python-sortedcontainers'
)
checkdepends=(
'python-ddt'
'python-jsonschema'
'python-lxml'
'python-toml'
'xmldiff'
)
makedepends=(
'python-build'
'python-installer'
'python-poetry'
'python-wheel'
)
conflicts=('python-cyclonedx-lib-git')
options=('!strip')
source=("${_gitpkgname}-${pkgver}.tar.gz::https://github.com/CycloneDX/cyclonedx-python-lib/archive/refs/tags/v${pkgver}.tar.gz")
sha512sums=('b6150c861514456d36761e959ab8b0fd66fced7e3dc33f932d9105f0e86297fcacc8e8057fb36f861a5f4006264705844c76997d42f2bc52eef5a7c0dbeb1bbf')
prepare() {
cd "${srcdir}/${_gitpkgname}-${pkgver}"
rm -rf dist # https://github.com/python-poetry/poetry/issues/1329
}
build() {
cd "${srcdir}/${_gitpkgname}-${pkgver}"
python -m build --wheel --no-isolation
}
check() {
cd "${srcdir}/${_gitpkgname}-${pkgver}"
python -m venv --clear --system-site-packages \
.venv
# shellcheck disable=SC1091
source .venv/bin/activate
pip install --force-reinstall dist/*.whl
python -m unittest discover -v
deactivate
}
package() {
cd "${srcdir}/${_gitpkgname}-${pkgver}"
python -I -m installer --destdir="${pkgdir}" dist/*.whl
install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
|