PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=python-del2rpp
pkgver=0.1.0
pkgrel=1
pkgdesc='Tool for converting Synthstrom Audible Deluge songs to REAPER projects'
arch=('any')
url='https://github.com/dcower/del2rpp'
license=('MIT')
depends=(
  'python'
  'python-pydel'
  'python-rpp'
  'python-attrs'
)
makedepends=(
  'git'
  'python-build'
  'python-installer'
  'python-wheel'
  'python-setuptools'
)
_commit='d0afa4ec39c2060b44e772f87a6700807d8d8155'
source=("$pkgname::git+$url#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd "$pkgname"

  # no tagged releases
  grep '^    version' setup.py | sed -e "s/^.*='//" -e "s/',//"
}

build() {
  cd "$pkgname"

  python -m build --wheel --no-isolation
}

package() {
  cd "$pkgname"

  python -m installer --destdir="$pkgdir" dist/*.whl

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}