blob: 00c342069ed9488d818e2abf47452ea3d519746a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: éclairevoyant
# Contributor: xiretza <xiretza+aur at gmail dot com>
pkgname=python-discord
pkgver=2.3.0
_tarname=discord.py-$pkgver
pkgrel=1
pkgdesc="Discord API wrapper written in Python"
arch=(any)
url="https://github.com/Rapptz/discord.py"
license=(MIT)
depends=('python-aiohttp>=3.7.4' 'python-aiohttp<4')
makedepends=(python-setuptools python-{build,installer,wheel})
optdepends=(
'python-pynacl>=1.3.0: voice support'
'libffi: voice support'
'python-orjson>=3.5.4: speed support'
'python-aiodns: speed support'
'python-brotli: speed support'
'python-cchardet=2.1.7: speed support'
'python<3.10: speed support'
)
source=("$_tarname.tar.gz::$url/archive/v$pkgver.tar.gz")
b2sums=('c06dfd3a58e209ab2c910b320ec03480f9f404bc049b7886e939b23f77012fcd97f4ad63cd30a663dbe7a3c18fa00c02f387c99fafdc857840c8bc1617799a4e')
build() {
cd $_tarname
python -m build -wn
}
package() {
cd $_tarname
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
python -m installer -d "$pkgdir" dist/*.whl
}
|