blob: 41d697f4240a2f135ba2789f8233c4d42e2221db (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Amos Onn <amosonn at gmail dot com>
# Maintainer: Blair Bonnett <blair dot bonnett @ gmail dot com>
pkgname=python-distributed
_pkgname=distributed
pkgver=2.15.0
pkgrel=1
pkgdesc="Python library for distributed computing"
arch=('any')
depends=(
'python' 'python-click' 'python-cloudpickle' 'python-dask' 'python-msgpack'
'python-psutil' 'python-sortedcontainers' 'python-tblib' 'python-toolz'
'python-tornado' 'python-zict' 'python-yaml'
)
optdepends=(
'python-cytoolz: Cython version of python-toolz for improved performance'
# Packages suggested in dev-requirements.txt
'python-joblib: Joblib integration'
'python-pandas: Pandas integration'
'python-numpy: NumPy integration'
'python-bokeh: Interactive visualisation of scheduler tasks'
'python-pyzmq: Asynchronous messaging with ZeroMQ'
'python-ipykernel: IPython integration for computing and debugging'
'python-prometheus_client: Prometheus integration for monitoring and alerting'
# Packages which have optional unit tests (pytest.importorskip calls)
'python-keras: Support for the Keras deep learning library'
'python-lz4: LZ4 compression of messages'
'python-netcdf4: Support for netCDF4 data files'
'python-numba: JIT compilation of code'
'python-h5py: Support for the HDF5 binary data format'
'python-asyncssh: Computing cluster using SSH communication'
'python-pytorch: Support for tensors and dynamic neural networks'
'python-ipywidgets: Extra widgets in diagnostic pages'
)
makedepends=('python-setuptools')
url="https://distributed.dask.org/"
license=('BSD')
source=(
"https://files.pythonhosted.org/packages/source/d/distributed/distributed-$pkgver.tar.gz"
)
sha256sums=(
'5c99b9a672af397e438779230596a774da3a07a4aaf2083ed9e3fc105daf8998'
)
build() {
cd "$_pkgname-$pkgver"
python setup.py build
}
package() {
cd "$_pkgname-$pkgver"
python setup.py install --skip-build --root="$pkgdir" --prefix=/usr --optimize=1
install -d "$pkgdir/usr/share/licenses/$pkgname"
install LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname"
}
|