PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Majorx234 <majorx234@gmail.com>

_pkgname=docling-parse
_pipname="${_pkgname//-/_}"
pkgname="python-${_pkgname}"
pkgver=5.6.1
pkgrel=1
pkgdesc="Simple package to extract text with coordinates from programmatic PDFs"
arch=('any')
url="https://github.com/docling-project/docling-parse"
license=('MIT')
depends=(python-docling-core
         # python-tabulate # already required by python-docling-core
         # python-pillow # already required by python-docling-core
         # python-pydantic # already required by python-docling-core
)
makedepends=('python-build' 'python-installer' 'python-pdm-backend' 'python-wheel' 'python-hatchling')
source=("$pkgname-$pkgver.tar.gz::https://github.com/docling-project/docling-parse/archive/refs/tags/v${pkgver}.tar.gz"
        "pyproject_toml_dep.patch")
sha256sums=('d976535236dce21938e48c0d52ea1e863b149894362c531fa1438878ad9ad36a'
            '6aa1dbab5fce06713bdc6a4ba81edc167f7e6913563391207b13317816854336')

prepare() {
    cd "${_pkgname}-${pkgver}"
    patch -Np1 -i "${srcdir}/pyproject_toml_dep.patch"
}

build() {
    cd "${_pkgname}-${pkgver}"
    python -m build --wheel --no-isolation
}

package() {
    cd "${_pkgname}-${pkgver}"
    python -m installer --destdir="${pkgdir}" --compile-bytecode 2 dist/*.whl
}