summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9f4b38c29cf1b2e87bc0aa51022845324f4a8577 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
# Maintainer: Astro Benzene <universebenzene at sina dot com>
pkgbase=python-einsteinpy-git
_gitname=einsteinpy
pkgname=("python-${_gitname}-git" "python-${_gitname}-doc-git")
pkgver=0.3.1.r29.g6285c79
pkgrel=1
pkgdesc="Python package for General Relativity"
arch=('i686' 'x86_64')
url="https://einsteinpy.org"
license=('MIT')
makedepends=('git' 'python-setuptools' 'python-scipy' 'python-nbsphinx' 'pandoc' 'graphviz')
checkdepends=('python-pytest-doctestplus' 'python-matplotlib' 'python-sympy' 'python-plotly' 'python-astropy' 'python-numba' 'python-einsteinpy_geodesics')
source=("git+https://github.com/einsteinpy/einsteinpy")
md5sums=('SKIP')

pkgver() {
    cd "${srcdir}/${_gitname}"

    ( set -o pipefail
      git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
      printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    )
}

#prepare() {
#    cd ${srcdir}/${_gitname}
#
#    sed '/julia/s/False/True/g' -i tests/test_plotting/test_geodesic/test_interactive.py \
#        -i tests/test_plotting/test_geodesic/test_static.py -i tests/test_geodesic/test_geodesic.py
#}

build() {
    cd ${srcdir}/${_gitname}
    python setup.py build

    msg "Building Docs"
    PYTHONPATH="build/lib" python setup.py build_sphinx
}

check() {
    cd ${srcdir}/${_gitname}

    PYTHONPATH="build/lib" pytest tests
}

package_python-einsteinpy-git() {
    depends=('python>=3.6' 'python-astropy' 'python-matplotlib' 'python-plotly' 'python-sympy' 'python-numba')
    optdepends=('python-einsteinpy-doc: Documentation for EinsteinPy')
    provides=("${pkgname%-git}")
    conflicts=("${pkgname%-git}")
    cd ${srcdir}/${_gitname}

    install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}" COPYING
    install -D -m644 README.rst *.ipynb -t "${pkgdir}/usr/share/doc/${pkgname}"
    python setup.py install --root=${pkgdir} --prefix=/usr --optimize=1
}

package_python-einsteinpy-doc-git() {
    pkgdesc="Documentation for EinsteinPy"
    provides=("${pkgname%-git}")
    conflicts=("${pkgname%-git}")
    cd ${srcdir}/${_gitname}/build/sphinx

    install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}" ../../COPYING
    install -d -m755 "${pkgdir}/usr/share/doc/${pkgbase}"
    cp -a html "${pkgdir}/usr/share/doc/${pkgbase}"
}