blob: b57785778b8b03789a50c558d5fc9158af9aeacc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
pkgname=python-environ-config
_name=${pkgname#python-}
pkgver=23.2.0
pkgrel=4
pkgdesc="Python Application Configuration With Environment Variables"
arch=(any)
url="https://github.com/hynek/environ-config"
license=(Apache-2.0)
depends=(
python
python-attrs
)
makedepends=(
python-build
python-hatch-fancy-pypi-readme
python-hatch-vcs
python-installer
python-wheel
)
checkdepends=(
python-moto
python-pytest
)
optdepends=('python-boto3: secret extraction from AWS Secrets Manager')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('b717dbdf671a79b8c73427bc2c8eeaabed7abf36252281accfd5db25b50db21a')
_archive="$_name-$pkgver"
build() {
cd "$_archive"
export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
python -m build --wheel --no-isolation
}
check() {
cd "$_archive"
rm -rf tmp_install
python -m installer --destdir=tmp_install dist/*.whl
_site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
export PYTHONPATH="$PWD/tmp_install/$_site_packages:$PYTHONPATH"
pytest \
--deselect tests/test_packaging.py::TestLegacyMetadataHack
}
package() {
cd "$_archive"
python -m installer --destdir="$pkgdir" dist/*.whl
}
|