PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Maintainer: Astro Benzene <universebenzene at sina dot com>
pkgbase=python-ezpadova-git
pkgname=('python-ezpadova-git' 'python2-ezpadova-git')
pkgver=r59.1b71cd7
pkgrel=1
pkgdesc="A python package that allows you to download PADOVA isochrones directly from their website"
arch=('i686' 'x86_64')
url="https://github.com/mfouesneau/ezpadova"
license=('MIT')
makedepends=('python' 'python2')
checkdepends=('python-pytest' 'python2-pytest' 'python-astropy' 'python2-astropy')
source=("git+https://github.com/mfouesneau/ezpadova.git")
md5sums=('SKIP')
_gitname=ezpadova

pkgver() {
    cd "${srcdir}/${_gitname}"

    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd ${srcdir}/${_gitname}

    cp -a ${srcdir}/${_gitname}{,-py2}
}

build() {
    cd ${srcdir}/${_gitname}
    python setup.py build

    msg "Building Python2"
    cd ${srcdir}/${_gitname}-py2
    python2 setup.py build
}

check() {
    cd ${srcdir}/${_gitname}
    python setup.py test

    cd ${srcdir}/${_gitname}-py2
    python2 setup.py test
}

package_python-ezpadova-git() {
    depends=('python')
    cd ${srcdir}/${_gitname}

    install -D -m644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname%-git}"
    install -D -m644 README.md -t "${pkgdir}/usr/share/doc/${pkgname%-git}"
    python setup.py install --root=${pkgdir} --prefix=/usr --optimize=1
}

package_python2-ezpadova-git() {
    depends=('python2')
    cd ${srcdir}/${_gitname}-py2

    install -D -m644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname%-git}"
    install -D -m644 README.md -t "${pkgdir}/usr/share/doc/${pkgname%-git}"
    python2 setup.py install --root=${pkgdir} --prefix=/usr --optimize=1
}