blob: 941fa6ce4a0dfb7161b7fd134a955f998a6454b2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer:
# Contributor: reggiiie
_module='ffmpeg-python'
_pkgname="python-$_module"
pkgname="$_pkgname-git"
pkgver=0.2.0.r41.gdf129c7
pkgrel=2
pkgdesc="(old) Python bindings for FFmpeg with complex filtering support"
url="https://github.com/kkroening/ffmpeg-python"
license=('Apache-2.0')
arch=(any)
depends=(
'ffmpeg'
'python'
'python-future'
'python-graphviz'
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
checkdepends=(
'python-pytest'
'python-pytest-mock'
'python-pytest-runner'
)
options=(!emptydirs)
provides+=("$_pkgname")
conflicts+=(
"$_pkgname"
'python-python-ffmpeg'
)
_pkgsrc="$_module"
source=("$_pkgsrc"::"git+https://github.com/kkroening/ffmpeg-python")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgsrc"
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$_pkgsrc"
sed -i -e 's/collections.Iterable/collections.abc.Iterable/g' ffmpeg/_run.py
}
build() {
cd "$_pkgsrc"
python -m build --no-isolation --wheel
}
check(){
cd "$_pkgsrc"
pytest || true
}
package() {
cd "$_pkgsrc"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm0644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|