blob: cc4580999ffeee8d0570e54dc8813c1f45afbd20 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer:
# Contributor: reggiiie
_module="ffmpeg-python"
_pkgname="python-$_module"
pkgname="$_pkgname-git"
pkgver=0.2.0.r41.gdf129c7
pkgrel=1
pkgdesc="(old) Python bindings for FFmpeg with complex filtering support"
arch=(any)
url="https://github.com/kkroening/ffmpeg-python"
license=('Apache')
options=(!emptydirs)
depends=(
'ffmpeg'
'python-future'
'python-graphviz'
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
checkdepends=(
'python-pytest'
'python-pytest-mock'
)
provides=(
"$_pkgname"
'python-ffmpeg'
)
conflicts=(
# ${provides[@]}
"$_pkgname"
'python-python-ffmpeg'
)
replaces=('python-ffmpeg-git')
source=(
"$_module"::"git+https://github.com/kkroening/ffmpeg-python"
)
sha256sums=(
'SKIP'
)
pkgver() {
cd "$srcdir/$_module"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$srcdir/$_module"
sed -i -e 's/collections.Iterable/collections.abc.Iterable/g' ffmpeg/_run.py
}
build() {
cd "$srcdir/$_module"
python -m build --no-isolation --wheel
}
check(){
cd "$srcdir/$_module"
pytest || true
}
package() {
cd "$srcdir/$_module"
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm0644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
|