PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Mohamed Amine Zghal (medaminezghal) <medaminezghal at outlook dot com>

_name=ffmpy
pkgname=python-${_name}
pkgver=0.6.0
pkgrel=1
pkgdesc="A simple Python wrapper for FFmpeg."
arch=(any)
url="https://github.com/Ch00k/ffmpy"
license=(MIT)
source=("${url}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('e8a6dfb3d88f13dd6cc5f55dae116a6ec2cf95e5ebf802bd0bfc5d6b0c23df4d')
depends=('python' 'ffmpeg')
makedepends=('python-uv-build' 'python-build' 'python-installer' 'python-wheel')
checkdepends=('python-pytest' 'python-pytest-cov')
optdepends=('python-psutil: psutil')

build() {
  cd "${srcdir}"/${_name}-${pkgver}
  python -m build --wheel --no-isolation
}

check() {
  local pytest_options=(
    -vv
  )
  cd "${srcdir}"/${_name}-${pkgver}
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl
  test-env/bin/python -m pytest "${pytest_options[@]}" tests
}

package() {
  cd "${srcdir}"/${_name}-${pkgver}
  python -m installer --destdir="$pkgdir" dist/*.whl
}