blob: 1c7a28b598e9b31f90fcd9abcc739c328185704d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer: Blair Bonnett <blair dot bonnett at gmail dot com>
pkgname=python-findpeaks
pkgver=2.7.5
pkgrel=1
pkgdesc="Detection of peaks and valleys in vectors and images"
url='https://erdogant.github.io/findpeaks/'
arch=('any')
license=('MIT')
depends=(
'python-adjusttext'
'python-caerus'
'python-joblib'
'python-matplotlib'
'python-numpy'
'python-pandas'
'python-requests'
'python-scipy'
'python-tqdm'
'python-xarray'
)
optdepends=(
'python-opencv: for working with images and loading examples'
'python-tabulate: to run example scripts'
)
makedepends=(
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
checkdepends=(
'python-opencv'
'python-pytest'
)
_pypi=findpeaks
source=(
"https://files.pythonhosted.org/packages/source/${_pypi::1}/$_pypi/$_pypi-$pkgver.tar.gz"
'change_opencv_message.patch'
)
sha256sums=(
'a84f2badc9cb8bde444e0348e24834ff0522a152db35ee3b86ba561417641c91'
'7d62b65268fa50830ad071ca1f92fe7165f09d3bebbde362c88c3bcd73bf32f9'
)
prepare() {
cd "$_pypi-$pkgver"
# Don't tell the user to install with pip, just raise the original exception
# and let them handle it.
patch -p0 -i "$srcdir/change_opencv_message.patch"
}
build() {
cd "$_pypi-$pkgver"
python -m build --no-isolation --wheel
}
check() {
cd "$_pypi-$pkgver"
rm -rf test-env
python -m venv --system-site-packages test-env
test-env/bin/python -m installer dist/"findpeaks-$pkgver"*.whl
test-env/bin/python -m pytest
}
package() {
cd "$_pypi-$pkgver"
python -m installer --destdir="$pkgdir" dist/"findpeaks-$pkgver"*.whl
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" "LICENSE"
# Remove unit tests from the final package.
local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
rm -r "$pkgdir/$site_packages/findpeaks/tests"
# Move the example script to /usr/share
install -Dm644 -t "$pkgdir/usr/share/$pkgname" findpeaks/examples.py
find "$pkgdir/usr/lib" -type f -name "examples.py" -exec rm '{}' \;
find "$pkgdir/usr/lib" -type f -name "examples.*pyc" -exec rm '{}' \;
}
|