blob: 4a7d5343c9b9874a38d8ba75d7cdb20f8f48bb5e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Guillaume Horel <guillaume.horel@gmail.com>
_pyname=fontParts
pkgname=python-${_pyname,,}
pkgver=0.11.0
pkgrel=1
pkgdesc='The replacement for RoboFab'
arch=(any)
url="https://github.com/robotools/${_pyname}"
license=(MIT)
_pydeps=(booleanoperations
defcon
fontmath
fontpens # for defcon[pens]
fonttools
fs # for fonttools[ufo]
lxml # for fonttools[lxml]
unicodedata2) # for fonttools[unicode]
depends=(python
"${_pydeps[@]/#/python-}")
makedepends=(python-{build,installer}
python-setuptools-scm
python-wheel)
_archive="$_pyname-$pkgver"
source=("https://files.pythonhosted.org/packages/source/${_pyname::1}/$_pyname/$_archive.zip")
sha256sums=('1dedc10085b1c0320cf348b19988f20079700caf5b05efea4bc3f8f935449048')
build() {
cd "$_archive"
python -m build -wn
}
check() {
cd "$_archive/Lib"
PYTHONPATH=. python "$_pyname/fontshell/test.py"
}
package() {
cd "$_archive"
python -m installer -d "$pkgdir" dist/*.whl
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
}
|