blob: 14199166ddfa9e1b50f6de27fcbd71997590df3c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: taotieren <admin@taotieren.com>
pkgname=python-fontparts-git
pkgver=0.11.0.r1.gf5250dc
pkgrel=1
pkgdesc='The replacement for RoboFab'
url='https://github.com/robotools/fontParts'
license=('MIT')
arch=(any)
_pydeps=(booleanoperations
defcon
fontmath
fontpens # for defcon[pens]
fonttools
fs # for fonttools[ufo]
lxml # for fonttools[lxml]
unicodedata2) # for fonttools[unicode]
depends=(python
"${_pydeps[@]/#/python-}")
makedepends=(python-{build,installer}
python-setuptools-scm
python-wheel)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --long --tags | sed 's/^v//g;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$pkgname"
python -m build -wn
}
check() {
cd "$pkgname/Lib"
PYTHONPATH=. python "fontParts/fontshell/test.py"
}
package() {
cd "$pkgname"
python -m installer -d "$pkgdir" dist/*.whl
}
|