blob: ef63693c250ee3cd0819251344a6c5d49f083e34 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: kriskras99 <admin at kriskras99 dot nl>
# Contributor: Ali Molaei <ali dot molaei at protonmail dot com>
# Contributor: algebro <algebro at tuta dot io>
_pkgname=frida
pkgname=python-$_pkgname
pkgver=16.2.1
pkgrel=1
pkgdesc="Inject JavaScript to explore native apps on Windows, Mac, Linux, iOS and Android. Python 3 version from PyPi"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url="https://www.frida.re"
license=('custom:wxWindows Library License, Version 3.1')
depends=('python'
'python-setuptools')
optdepends=('python-typing_extensions: for Python <3.8'
'rustup: for injecting Rust code into targets')
# Sourced from https://pypi.org/project/frida/#files
source=("https://files.pythonhosted.org/packages/source/f/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
"COPYING")
# Sourced from https://github.com/frida/frida/releases
source_i686=("frida-core-devkit-${pkgver}-linux.tar.xz::https://github.com/frida/frida/releases/download/${pkgver}/frida-core-devkit-${pkgver}-linux-x86.tar.xz")
source_x86_64=("frida-core-devkit-${pkgver}-linux.tar.xz::https://github.com/frida/frida/releases/download/${pkgver}/frida-core-devkit-${pkgver}-linux-x86_64.tar.xz")
source_armv7h=("frida-core-devkit-${pkgver}-linux.tar.xz::https://github.com/frida/frida/releases/download/${pkgver}/frida-core-devkit-${pkgver}-linux-armhf.tar.xz")
source_aarch64=("frida-core-devkit-${pkgver}-linux.tar.xz::https://github.com/frida/frida/releases/download/${pkgver}/frida-core-devkit-${pkgver}-linux-arm64.tar.xz")
sha256sums=('64a011825ea21a5ed3e3d7589f04c1dec473e1a083beb4c57895dddf32caa7c9'
'5ea1544b51a28bc823b03159190d4108f9fb4f4ef912389f5137c6d295e175b2')
sha256sums_i686=('60a7bc73333fb3a31290705827b06e3d240aeb9991ebfdc28ca51909ccbcd275')
sha256sums_x86_64=('ee2a6dc24f996bd0208d7d6b518b6f8bd45283cdb71d5f206bb1b4f40ea32265')
sha256sums_armv7h=('4d8491ce055bb665f8dcb6a281f7b298517ca02cf5c86145b2a3179651de99fc')
sha256sums_aarch64=('58815c55f1c4be0dfc14b38e3c2cdb9f0dfb810a0d85e5d8ecca3a89f541de03')
noextract=("frida-core-devkit-${pkgver}-linux.tar.xz")
conflicts=("python2-${_pkgname}")
prepare() {
mkdir "$srcdir/frida-core-devkit-${pkgver}-linux"
bsdtar -x --cd "$srcdir/frida-core-devkit-${pkgver}-linux" -f "frida-core-devkit-${pkgver}-linux.tar.xz"
}
build() {
cd "$srcdir/$_pkgname-$pkgver"
FRIDA_CORE_DEVKIT="../frida-core-devkit-${pkgver}-linux" python setup.py build
}
package() {
cd "$srcdir/$_pkgname-$pkgver"
FRIDA_CORE_DEVKIT="../frida-core-devkit-${pkgver}-linux" python setup.py install --root=$pkgdir --optimize=1 --skip-build
cd "$srcdir"
install -d "$pkgdir/usr/share/licenses/$pkgname"
install -m 644 "COPYING" "$pkgdir/usr/share/licenses/$pkgname/"
}
|