blob: 4ea34398acf1c30dfcec4bd8248fabc819fa4d33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
pkgbase=python-funcy
pkgname=('python-funcy' 'python2-funcy')
pkgver=1.10.1
pkgrel=1
pkgdesc='A fancy and practical functional tools'
arch=('any')
license=('BSD')
url='https://github.com/Suor/funcy'
makedepends=('python-setuptools' 'python2-setuptools')
checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-whatever' 'python2-whatever')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/Suor/funcy/archive/$pkgver.tar.gz")
sha512sums=('97b0c23e541d8d6a1a37e537fa80ce72fc1ef811df6e9b95ffae57e2345f74719d590e8fe9e76ba47b19f9f18baf1b97c9473e0a9941b13601f9af5b7f737a8c')
prepare() {
cp -a funcy-$pkgver{,-py2}
}
build() {
cd "$srcdir"/funcy-$pkgver
python setup.py build
cd "$srcdir"/funcy-$pkgver-py2
python2 setup.py build
}
check() {
cd "$srcdir"/funcy-$pkgver
python setup.py pytest
cd "$srcdir"/funcy-$pkgver-py2
python2 setup.py pytest
}
package_python-funcy() {
depends=('python')
cd funcy-$pkgver
python setup.py install --root="$pkgdir" --optimize=1
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
package_python2-funcy() {
depends=('python2')
cd funcy-$pkgver-py2
python2 setup.py install --root="$pkgdir" --optimize=1
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
# vim:set ts=2 sw=2 et:
|