blob: 109a09518ef291cb62c91487bdc9b30166665980 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
pkgbase=python-funcy
pkgname=('python-funcy' 'python2-funcy')
pkgver=1.10.3
pkgrel=2
pkgdesc='A fancy and practical functional tools'
arch=('any')
license=('BSD')
url='https://github.com/Suor/funcy'
makedepends=('python-setuptools' 'python2-setuptools')
checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-whatever' 'python2-whatever')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/Suor/funcy/archive/$pkgver.tar.gz")
sha512sums=('3ea72a596818b9bc8f89bf002634f595859588e5a2558416ceffa5703db60880c7fbaef8c0f9654b5d7d70b58e3b7282b53c295218d540dbc2a8a5b481562bb4')
prepare() {
cp -a funcy-$pkgver{,-py2}
}
build() {
cd "$srcdir"/funcy-$pkgver
python setup.py build
cd "$srcdir"/funcy-$pkgver-py2
python2 setup.py build
}
check() {
cd "$srcdir"/funcy-$pkgver
python setup.py pytest
cd "$srcdir"/funcy-$pkgver-py2
python2 setup.py pytest
}
package_python-funcy() {
depends=('python')
cd funcy-$pkgver
python setup.py install --root="$pkgdir" --optimize=1
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
package_python2-funcy() {
depends=('python2')
cd funcy-$pkgver-py2
python2 setup.py install --root="$pkgdir" --optimize=1
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
# vim:set ts=2 sw=2 et:
|